Linux安全网 - Linux操作系统_Linux 命令_Linux教程_Linux黑客

会员投稿 投稿指南 本期推荐:
搜索:
您的位置: Linux安全网 > Linux编程 > » 正文

AS3与JavaScript Object Notation的简单通信(AS3 JSON)

来源: liminxin272 分享至:

json是JavaScript Object Notation的简写,是一种轻量级的数据交换格式。易于人阅读和编写。同时也易于机器解析和生成。它是基于JavaScript(Standard ECMA-262 3rd Edition – December 1999)的一个子集,也就是说他是来自于javascript的东西。因为现在ajax的流行,大部分网站会采用ajax的模式和构架,那么json会是一个数据传输的首选(文本方式太简单,要是大数据量的时候无法理解,xml的方式数据量大,在解析的时候会增加服务器负担),那么要是一个网站从 ajax构架的基础上出一个flex/Flash版的界面的时候使用json会最少地减少服务器端的程序改动。

JSON的结构写法很容易理解,它原本就是以数据量小和清晰的数据格式而著称的。但是在AS中使用json其实并不是一个必须或是很好的选择,很多时候我们还是会用XML,因为AS对XML的解析已经很好了。
用XML表示如下:

<?xml version=”1.0″ encoding=”utf-8″?>
  <user>
  <name>张三 </name>
  <password>123456</password>
  <department>技术部</department>
  <sex>男</sex>
  <age>30</age>
  </user>

对于这样一个XML来说,如果数据量大了的确让人头昏眼花,也不好处理,但是如果我们转化成下面这种形式的话:

<?xml version=”1.0″ encoding=”utf-8″?>
  <user>
<people name=”张三” password=”123456″ depattment=”技术部” sex=”男” age=”30″ />
  </user>

再跟相应的JSON来比较:

{“name”:”张三”,”password”:”123456″,”department”:”技术部”,”sex”:”男”,”age”:”30″}

首先,你需要有一个JSON的类库,建议去下载adobe官方提供的产品外类库:http://code.google.com/p/as3corelib/ 。类库的使用就不多说了,大家应该都知道。
       先说说获取数据。可以这么说,只要你懂AS3与XML的交互,那么就一定能懂JSON,因为两者几乎是一样的,你唯一需要做的只是了解一下JSON的格式。例如下面这个JSON的例子,就像XML一样,你可以通过任何动态页面来生成这个格式,也可以通过静态的甚至TXT来读取也行。

[{"name":"Hans","age":"32"},
{"name":"John","age":"12"},
{"name":"Zaki","age":"34"},
{"name":"Dr. Cox","age":"88"}] 

AS中的代码:

package {
	import com.adobe.serialization.json.JSON;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLLoader;
	import flash.net.URLRequest;

	public class getJSON extends Sprite {
		public function getJSON() {
			var loader:URLLoader=new URLLoader  ;
			loader.load(new URLRequest("http://127.0.0.1/json.php"));//这里是你要获取JSON的路径
			loader.addEventListener(Event.COMPLETE,decodeJSON);
		}
		private function decodeJSON(evt:Event):void {
			var persons:Array=JSON.decode(URLLoader(evt.target).data);
			//在这里,就可以通过操作数组来应用数据了,很方便
			for (var i:int=0; i<persons.length; i++) {
				trace(persons[i].name);
			}
		}
	}
}

是不是很简单呢?在这里我们只用到了decode()这个方法,其实JSON类库要用的也只有两个方法,另一个就是马上要用到的encode()。大家可以理解为编码与解码。发送数据的代码如下:

package {
	
	import com.adobe.serialization.json.JSON;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.*;

	public class sendJSON extends Sprite {
		
		public function sendJSON() {
			var arr:Array=new Array({"name":"Hans","age":"32"},{"name":"John","age":"12"},{"name":"Zaki","age":"34"},{"name":"Dr. Cox","age":"88"});//这里是要发送的数据,可以直接写,也可以是由其他方法生成,不过要注意格式。
			sendjson(arr);
		}
		
		private function sendjson(a:Array):void {
			var jsonString:String=JSON.encode(a);

			var urlVariables:URLVariables=new URLVariables  ;
			urlVariables.json=jsonString;

			var urlRequest:URLRequest=new URLRequest("http://127.0.0.1/json.php");//这里是接收数据的动态页。
			urlRequest.method=URLRequestMethod.POST;
			urlRequest.data=urlVariables;

			//其实到这已经结束了,下面的XML只是测试结果而已。
			var urlLoader:URLLoader=new URLLoader  ;
			urlLoader.addEventListener(Event.COMPLETE,onURLLoaderCompleteEvent);
			urlLoader.load(urlRequest);
		}
		
		private function onURLLoaderCompleteEvent(evt:Event):void {
			var xml:XML=new XML(evt.target.data);
			trace(xml);
		}
	}
}


为了大家方便使用JSON格式与服务器通信,有高手写了一个JSONLoader加载器,我这里把代码贴出来,如下:

package 
{
	import com.adobe.serialization.json.JSON;
	
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.SecurityErrorEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.net.URLRequestMethod;
	import flash.net.URLVariables;
	import flash.utils.Dictionary;
	
	/**
	 * JSONLoader加载器,这个类是个工具类,可以同时加载多个xml数据 ,在JSONLoader内部使用奴隶与死囚优化法则来减小内存消耗。
	 * @author qiuxin
	 * 
	 */	
	public class JSONLoader extends URLLoader
	{
		private static var limbo:Dictionary=new Dictionary(true);
		
		private var loadding:Boolean;
		private var competeHandle:Function;
		
		
		public static function load(url:String, competeHandle:Function, variables:URLVariables=null, method:String="GET"):void
		{
			var request:URLRequest;
			var loader:JSONLoader
			
			//在缓存寻找非运作的loader
			for(var criminal:Object in limbo)
			{
				if(!JSONLoader(criminal).loadding)
				{
					loader=criminal as JSONLoader;
					request=limbo[loader] as URLRequest;
					request.url=url;
					break;
				}
			}
			//未找到则重新创建
			if (!loader)
			{
				request=new URLRequest(url);
				loader=new JSONLoader(request);
				limbo[loader]=request;
			}
			request.data=variables;
			request.method=method;
			loader.competeHandle=competeHandle;
			loader.load(request);
			loader.loadding=true;
		}
		
		
		public function JSONLoader(request:URLRequest=null)
		{
			super(request);
			
			addEventListener(Event.COMPLETE, xmlLoadComplete);
			addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandle);
			addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandle);
		}
		
		
		private function ioErrorHandle(event:IOErrorEvent):void
		{
			trace("加载xml时服务器未能返回");
		}
		
		
		private function securityErrorHandle(event:SecurityErrorEvent):void
		{
			trace("加载xml时发生安全沙箱错误");
		}
		
		
		private function xmlLoadComplete(event:Event):void
		{
			loadding=false;
			var result:Object=JSON.decode(event.target.data);
			competeHandle(result);
		}
	}
}

有了JSONLoader后在任何地方可以通过静态方法load()加载后台数据,加载完后自动调用每个数据的回调函数并且传入加载的xml。JSONLoader可以同时加载多个数据,由于JSONLoader在内部使用了内存优化(奴隶与死囚优化法则),频繁加载也不会带来内存溢出问题。






Tags:
分享至:
最新图文资讯
1 2 3 4 5 6
验证码:点击我更换图片 理智评论文明上网,拒绝恶意谩骂 用户名:
关于我们 - 联系我们 - 广告服务 - 友情链接 - 网站地图 - 版权声明 - 发展历史